;:poke56,117:clr
;:sys36864
	;.opt oo
	*= 30000	;2168
maxdat	=50	;199
data	=49152	;80*256
strout	=$ab1e
vic	=$d000
cint	=65409
clall	=$ffe7
spalte	=211
return	=$aad7
tmp	=2
setcur	=$e50c
chrout	=$ea1c
rechne	=58732
dofarb	=$ea24
art	=data+1
opt	=art+1
wer	=opt+40
cut	=wer+40
date	=cut+40
here	=date+9
color	=646
print	=$ffd2
space	=$ab3f
add05	=$b849
div	=$bb14
vz	=$66
integer	=$b801
intfac	=$bc49
facarg	=$bc0c
zeile	=214
bild	=$d1
key	=198
get	=65508
vorher	=here-60
revs	=199
crs1	=$cc
crs2	=$cd
crs3	=$cf
latch	=824
quote	=212
oben	=1024+40
buff	=631
pos	=65360
tem	=4
zal	=181
reset	=$fffc
setpar	=$ffba
setnam	=$ffbd
fina	=latch-2
flop	=8
bsave	=$ffd8
bload	=$ffd5
dirmod	=157
max1	=maxdat+1
m1	=max1*60
sch1	=m1+here
sch2	=sch1+40
sch3	=sch2+40
fac	=$62
facmem	=$bbd4
memmult	=$ba28
memplus	=$b867
memfac	=$bba2
memarg	=$ba8c
mult	=$ba2b
exp	=$61
scrab	=fina-2
fnlen	=183
close	=$ffc3
open	=$ffc0
clrchn	=$ffcc
chkout	=$ffc9
druck	=4
iost	=144
krep	=650
	jsr hploesch
	jmp start
tit	.byte "\x08\x13\x12\x90zensudat v2    n.heusler   (c) nh-091290"
	.byte "                                        \x1f\x92"
	.byte "            \xdd pruef#\xdd   \xdd   \xdd   \xdd   \xdd"
	.byt 13
	.byte "            \xddoptimum\xdd   \xdd   \xdd   \xdd   \xdd"
	.byt 13
	.byte "name        \xdd   wert\xdd   \xdd   \xdd   \xdd   \xdd"
	.byt 13
	.byte "\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xb1\xc0\xc0\xc0\xc0\xc0\xc0\xc0\xdb\xc0\xc0\xc0\xdb\xc0\xc0\xc0\xdb\xc0\xc0\xc0\xdb\xc0\xc0\xc0\xdb\xc0\xc0"
	brk
einz	.byte "\xdd   \xdd   \xdd   \xdd   \xdd"
	brk
unten	.byt 13
	.byte "\x12durchschnitt        \xdd   \xdd   \xdd   \xdd   \xdd  \x13"
	brk
delt	.byte "\x9d \x9d"
	brk
updn	.byte "\x13\x11\x90\x12auf (+), ab (-), stop (_)"
	brk
sorte	.byte "\x13\x11\x90\x12sortierung"
	brk
surt	.byte "\x13\x11\x90\x12sind sie sicher ? (j/n)"
	brk
tellt	.byte "\x13\x11\x90\x12\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d\x1d"
	brk
fna	.byte "feldinhalt?"
	brk
fnb	.byte "filename?"
	brk
svg	.byte "\x13\x11\x90\x12speichere"
	brk
ldg	.byte "\x13\x11\x90\x12lade"
	brk
fnc	.byte "optimum?"
	brk
fnd	.byte "datum?"
	brk
dartab	.byte "zna\x1dtrw\x1dnsd\x1f\x92"
pfetab	.byte " \xbb\xac\x1d \xbb\xac\x1d \xbb\xac\x1f"
unttab	.byte " \xa9\xdf\x1d \xa9\xdf\x1d \xa9\xdf\x1f"
calce	.byte "\x13\x11\x90\x12berechne werte"
	brk
anne	.byte "\x13\x11\x90\x12bitte drucker einschalten! (_ = abbr.)"
	brk
katja	.byte "\x13\x11\x90\x12druckvorgang laeuft (_ = abbr.)"
	brk
wasd	.byte "\x13\x11\x90\x12(z)eile, (s)palte, stop (_)"
	brk
pt1	.byte "zensudat v2      von n. heusler    (c) 90/91    "
	brk
pt2	.byt 13
	.byte "nr. name                    "
pt3	.byte "       "
	brk
pt3a	.byte "punkte"
pt3b	.byte " note "
ptd	.byte " schnitt  gewertet  anzahl"
	brk
pt4	.byte "namenliste:"
	.byt 13,0
pt5	.byte "pruefung nr. "
	brk
pt6	.byte ",  beste zensur: "
	brk
pt7	.byt 13
	.byte "wertung: "
	brk
pt8	.byte "fach"
	brk
pt9	.byte "zensurenliste fuer "
	brk
pta	.byte "    durchschnitt"
	brk
ptb	.byte "pruef. !"
	brk
ptca	.byte "punkte !"
	brk
ptcb	.byte "note   !"
	brk
pte	.byte "liste der endergebnisse"
	brk
ptf	.byte "  (schulnoten"
pth	.byte "):"
	.byt 13,0
ptg	.byte "  (optimum "
	brk
adda	=139
addb	=141
y	=251 	; nr. des ersten schuelers
x	=250 	; nr. der ersten pruefung
zif	=249 	; ziffer
command	=6
eimod	=167	; ausgabe-modus
cx	=253 	; cursorpos. rel.
cy	=252
ymem	=178
xmem	=179
inmode	=166 	; flag nur ziffern
sortpos	=168
sortflg	=169
nr	=254 	; lfd. nr. des schuelers
end	=248 	; letzte lfd. nr
darst	=247	; flag anzeige der durchschnitte
opti	=704 	; flp beste note
add	=opti+5 	; flp addition
anz	=171	; anz. messwerte/druckmodus
ax	=170	; cx+x
bopt	=$92
puno	.byt 6,5,4,3,2,1,0
dez	.byt 10,100
curl	.byt 20,3,3,3,3,3
curs	.byt 0,21,25,29,33,37
beftab	.byte "\x11\x91\x1d\x9d\x13\x93-AESLBCDPKM"
befadr	.word down,up,right,left,home,clear,stric
	.word sort,ende,save,load,schnitte,einraus
	.word datum,printer,rauspruef,artsw
calcx	cpx #-1
	beq atten
	lda #0
	sta adda+1
	txa
	asl
	rol adda+1
	asl
	rol adda+1
	sta adda
	sta addb
	lda adda+1
	sta addb+1
	ldx #3
mal60	asl addb
	rol addb+1
	lda adda
	adc addb
	sta adda
	lda adda+1
	adc addb+1
	sta adda+1
	dex
	bne mal60
	lda adda
	clc
	adc #<here
	sta tmp
	lda adda+1
	adc #>here
	sta tmp+1
	rts
atten	lda #<vorher
	sta tmp
	lda #>vorher
	sta tmp+1
	rts
calccut	lda #20
	sta addb+1
cc1	ldx #0
	stx adda
	stx adda+1
	stx addb
	lda #<here
	ldy #>here
	sta tmp
	sty tmp+1
cc2	cpx data
	bcs cc3
	ldy addb+1
	lda (tmp),y
	cmp #-1
	beq cc4
	adc adda
	sta adda
	lda #0
	adc adda+1
	sta adda+1
	inc addb
cc4	jsr tp60
	inx
	bne cc2
cc3	lda addb
	bne cc6
	lda #-1
	bne cc7
cc6	pha
	lda adda
	ldx adda+1
	jsr bytfac
	jsr facarg
	pla
	jsr byt0fac
	jsr div
	jsr int
cc7	ldy addb+1
	sta cut-20,y
	inc addb+1
	cpy #59
	bcs cc8
	jmp cc1
cc8	rts
tp60	lda tmp
	clc
	adc #60
	sta tmp
	bcc tpok
	inc tmp+1
tpok	rts
byt0fac	ldx #0
bytfac	sta fac+1
	stx fac
	ldx #144
	sec
	jsr intfac
	lsr vz
	rts
int	lsr vz
	jsr add05
	jsr integer
	tya
	rts
cursor	lda #0
	sta eimod
	lda cy
	clc
	adc #2
	sta zeile
	jsr rechne
	ldx cx
	ldy curs,x
	lda curl,x
	tax
ive	lda (bild),y
	eor #128
	sta (bild),y
	iny
	dex
	bne ive
	ldx #4
	ldy #9
	jsr setcur
	lda cy
	cmp #4
	bcs nos
	lda #5
nos	sbc #4
	adc y
num	jsr arith
	jmp do4
vnum	jsr deco
	jmp num
deco	bit art
	bpl lass
	cmp #-1
	beq lass
	stx xmem
	tax
	lda puno,x
	ldx xmem
lass	rts
arith	sty ymem
	stx xmem
	cmp #-1
	beq strich
	ldx #1
n1	ldy #"0"
	sty zif
n2	cmp dez,x
	bcc n3
	sbc dez,x
	inc zif
	bne n2
n3	ldy zif
	sty zal+1,x
	dex
	bpl n1
	ora #"0"
	sta zal
	lda zal+2
	cmp #48
	bne n4
	lda #32
	sta zal+2
	lda zal+1
	cmp #48
	bne n4
	lda #32
	sta zal+1
n4	rts
do4	jsr rechne
	jsr dofarb
	lda zal+2
	jsr eiout
	lda zal+1
	jsr eiout
	lda zal
	jsr eiout
	ldx xmem
	ldy ymem
	inc spalte
	rts
void	lda #"*"
	sta zal
	sta zal+1
	sta zal+2
	bne do4
strich	lda #32
	sta zal+1
	sta zal+2
	lda #"-"
	sta zal
	bne n4
eiout	ldx eimod
	beq ei1
	eor #128
	ldx #6
	.byt $2c
ei1	ldx #1
	jsr chrout
	inc spalte
	rts
d0	lda #0
	sta darst
	rts
out	lda #0
	sta eimod
	ldx #2
	ldy #21
	jsr setcur
	lda darst
	beq norm
	jmp dar1
norm	ldy #4
	ldx x
nrout	txa
	clc
	adc #1
	tax
	jsr num
	dey
	bpl nrout
	ldx #3
	ldy #21
	jsr setcur
	lda art
	bpl opok
	ldx #5
opste	stx xmem
	jsr void
	ldx xmem
	dex
	bne opste
	beq op2
opok	ldy #4
	ldx x
opout	lda opt,x
	jsr num
	inx
	dey
	bpl opout
op2	ldx #4
	ldy #21
	jsr setcur
	ldy #4
	ldx x
weout	lda wer,x
	jsr num
	inx
	dey
	bpl weout
cont1	lda y
	pha
	lda #18
	sta nr
	jsr return
	jsr return
	ldx y
	dex
	jsr calcx
s1	ldx #1
	stx color
	ldx y
	cpx data
	bcs s5
	jsr tp60
	ldy #0
s2	lda (tmp),y
	and #127
	cmp #32
	bcs cok
	ora #32
cok	jsr print
	iny
	cpy #20
	bcc s2
	ldx darst
	beq nom
	jmp dar6
nom	ldx #4
	tya
	clc
	adc x
	tay
	inc spalte
s3	lda (tmp),y
	jsr vnum
	iny
	dex
	bpl s3
	bmi s4
s5	ldx #20
s6	jsr space
	dex
	bne s6
	ldx #5
s7	jsr trispa
	dex
	bne s7
s4	lda #0
	sta spalte
	jsr return
	inc y
	dec nr
	bne s1
	pla
	sta y
	ldx #24
	ldy #21
	jsr setcur
	ldy #4
	ldx x
	sty eimod
cuout	lda cut,x
	jsr vnum
	inx
	dey
	bpl cuout
	bmi datout
trispa	txa
	pha
	inc spalte
	jsr space
	jsr space
	jsr eiout
	pla
	tax
	rts
dar1	ldx #12
dar2	lda dartab,x
	jsr print
	dex
	bpl dar2
	jsr clrrest
	ldx #3
	ldy #21
	jsr setcur
	ldx #11
dar4	lda pfetab,x
	jsr print
	dex
	bpl dar4
	jsr clrrest
	ldx #4
	ldy #21
	jsr setcur
	ldx #11
dar5	lda unttab,x
	jsr print
	dex
	bpl dar5
	jsr clrrest
	jmp cont1
dar6	inc spalte
	ldy y
	lda sch1,y
	jsr vnum
	lda sch2,y
	jsr vnum
	lda sch3,y
	jsr num
	dec spalte
	jsr clrrest
	jmp s4
datout	ldx #2
	ldy #0
	jsr setcur
	lda #1
	sta color
	lda #<date
	ldy #>date
	jsr strout
	lda #" "
	ldy spalte
filldt	cpy #12
	bcs filled
	sta (bild),y
	iny
	bne filldt
filled	rts
clrrest	ldx #1
	stx color
	inx
dar3	jsr trispa
	dex
	bne dar3
	rts
getkey	lda #0
	sta key
gk	cmp key
	beq gk
	jmp get
tell	lda #<tellt
	ldy #>tellt
st	jmp strout
tellfel	jsr cursor
	jsr tell
	jsr inbuf
	lda #<fna
	ldy #>fna
	bne st
namein	jsr tell
	lda #<fnb
	ldy #>fnb
	jsr strout
	lda #0
	ldx #14
	jsr input
	beq schiss
	ldy #"z"
	sty fina
	ldy #"."
	sty fina+1
	ldy #"s"
	sty scrab
	inx
	inx
	ldy #":"
	sty scrab+1
schiss	rts
setdpar	ldx #<fina
	ldy #>fina
	jsr setnam
	ldx #flop
	ldy #0
	sty dirmod
	jsr setpar
	rts
input	sta inmode
	stx tmp+1
	ldx #1
	ldy #0
	jsr setcur
	ldx #0
	stx color
	stx tmp
	inx
	stx revs
keylp	lda #0
	sta crs1
	jsr gk
	ldx #1
	stx crs2
woff	ldx crs3
	bne woff
	inc crs1
	cmp #13
	beq retend
	cmp #20
	beq delay
	ldx tmp
	cpx tmp+1
	bcs keylp
	and #127
	cmp #32
	bcs ok
	jmp keylp
ok	bit inmode
	bpl rok
	cmp #48
	bcc keylp
	cmp #58
	bcs keylp
rok	sta latch,x
	jsr print
	lda #0
	sta quote
	inc tmp
	bne keylp
delay	ldx tmp
	beq keylp
	lda #<delt
	ldy #>delt
	jsr strout
	dec tmp
	bpl keylp
retend	jsr clrob
	ldx tmp
	lda #0
	sta latch,x
	txa
	rts
inbuf	lda #1
	sta key
	lda command
	sta buff
	rts
wert	ldx #0
	stx tmp
we1	ldy latch,x
	beq we3
	lda tmp
	asl
	bcs we2
	sta tmp
	asl
	bcs we2
	asl
	bcs we2
	adc tmp
	sta tmp
	bcs we2
	tya
	and #15
	cmp #10
	bcs we2
	adc tmp
	sta tmp
	inx
	bne we1
we2	sec
	rts
we3	lda tmp
	clc
	rts
sure	lda #<surt
	ldy #>surt
	jsr strout
gjn	jsr getkey
	cmp #"j"
	beq yes
	cmp #"n"
	bne gjn
	lda #0
	.byt $2c
yes	lda #-1
	pha
	jsr clrob
	pla
	rts
print1	jsr clrchn
	ldx #druck
	lda #1
	ldy #0
	jsr setpar
	lda #1
	pha
	jsr close
	pla
	jsr open
	ldx #1
	jsr chkout
	jsr return
	jsr clrchn
	lda iost
	bpl geht
	lda #<anne
	ldy #>anne
	jsr strout
	jsr get
	cmp #"_"
	bne print1
	rts
geht	jsr clrob
	lda #<katja
	ldy #>katja
	jsr strout
	ldx #1
	jsr chkout
	lda #<pt1
	ldy #>pt1
	jsr strout
	lda #<date
	ldy #>date
	jsr strout
	jsr return
dot	ldx #56
rdot	lda #"-"
dotout	jsr print
	dex
	bne dotout
	jmp return
print0	jsr return
	jsr clrchn
	lda #1
	jsr close
clrob	ldx #39
	lda #160
cob	sta oben,x
	dex
	bpl cob
	rts
dpnum	jsr deco
pnum	jsr psnum
	jsr space
	ldx xmem
	ldy ymem
	rts
xspa	jsr space
	dex
	bne xspa
	rts
psnum	jsr arith
	lda zal+2
	jsr print
	lda zal+1
	jsr print
	lda zal
	jmp print
start	jsr cint
	jsr clall
	jsr init
	lda #0
	sta vic+32
	lda #12
	sta vic+33
	lda #128
	sta krep
	lda #<tit
	ldy #>tit
	jsr strout
	ldx #18
build	txa
	pha
	jsr return
	lda #20
	sta spalte
	lda #<einz
	ldy #>einz
	jsr strout
	pla
	tax
	dex
	bne build
	lda #<unten
	ldy #>unten
	jsr strout
	lda 1262
	sta 1263
	lda 55534
	sta 55535
	lda 2022
	sta 2023
	lda 56294
	sta 56295
	jsr out
main	jsr cursor
getbef	jsr getkey
	ldx #befadr-beftab-1
	sta command
subef	cmp beftab,x
	beq beff
	dex
	bpl subef
	cmp #"a"
	bcc nolet
	cmp #"z"+1
	bcc letter
nolet	cmp #"0"
	bcc getbef
	cmp #"9"+1
	bcs getbef
	lda #<ziffer
	ldy #>ziffer
	bne setbef
letter	lda #<buch
	ldy #>buch
	bne setbef
beff	txa
	asl
	tax
	ldy befadr+1,x
	lda befadr,x
setbef	sta tmp
	sty tmp+1
	jsr cursor
	jsr call
	jmp main
call	jmp (tmp)
init	jsr d0
	sta x
	sta y
	sta cx
	lda #4
	sta cy
	rts
right	lda cx
	cmp #5
	bcs scr1
	inc cx
off	rts
scr1	lda x
	cmp #35
	bcs off
	inc x
mnew	jsr d0
new	jmp out
left	lda cx
	beq scr2
	dec cx
	cmp #1
	bne off
	lda #4
	cmp cy
	bcc off
	sta cy
	bne off
scr2	lda x
	beq off
	dec x
	bpl mnew
up	lda cy
	bit art
	bpl up0
	cmp #3
	jmp up1
up0	cmp #2
up1	bcc scr3
	dec cy
	cmp #4
	bne off
	dec cy
	lda cx
	bne off
	inc cx
	bne off
scr3	lda y
	beq off
	dec y
	jmp new
down	lda cy
	clc
	adc y
	cmp #4
	bcc okdn
	sbc #4
	cmp data
	bcs off
okdn	lda cy
	cmp #21
	bcs scr4
	inc cy
	cmp #2
	bne off
	inc cy
	bne off
scr4	inc y
	bne new
home	jsr d0
	lda cx
	bne local
	lda cy
	cmp #4
	bne local
global	jsr init
local	lda #4
	sta cy
	lda #0
	sta cx
	jmp new
hploesch	lda #0
	sta art
loesch	lda #0
	sta data
	sta date
	lda #-1
	ldx #39
cler	sta opt,x
	sta wer,x
	sta cut,x
	dex
	bpl cler
	rts
clear	jsr sure
	beq hilf
putzweg	jsr d0
	jsr loesch
	bmi global
hilf	rts
ende	jsr sure
	beq hilf
	jmp (reset)
save	jsr namein
	beq frist
	inx
	inx
	txa
	ldx #<scrab
	ldy #>scrab
	jsr setnam
	ldx #flop
	lda #15
	tay
	jsr setpar
	pha
	pha
	jsr close
	pla
	jsr open
	pla
	jsr close
	ldx fnlen
	dex
	dex
	txa
	jsr setdpar
	lda #<svg
	ldy #>svg
	jsr strout
	ldx data
	jsr calcx
	ldx tmp
	ldy tmp+1
	lda #<data
	sta tmp
	lda #>data
	sta tmp+1
	lda #tmp
	jsr bsave
	jmp clrob
load	jsr namein
	beq frist
	txa
	jsr setdpar
	jsr d0
	lda #<ldg
	ldy #>ldg
	jsr strout
	ldx #<data
	ldy #>data
	lda #0
	jsr bload
	jsr calccut
	jsr global
	jmp clrob
frist	rts
einraus	lda cy
	cmp #4
	bcc frist
	sbc #4
	clc
	adc y
	cmp data
	bcs frist
	dec data
	tax
	stx nr
	jsr calcx
delloop	ldx nr
	cpx data
	bcs enddel
	lda tmp
	clc
	adc #60
	sta tem
	lda tmp+1
	adc #0
	sta tem+1
	ldy #59
delin	lda (tem),y
	sta (tmp),y
	dey
	bpl delin
	jsr tp60
	inc nr
	bne delloop
enddel	jsr calccut
	jsr d0
	jmp out
rauspruef	lda cx
	beq frist
	clc
	adc x
	tax
	dex
	clc
	adc #19
	tay
	lda #-1
	sta wer,x
	sta opt,x
	ldx #0
	stx nr
	jsr calcx
sekdel	lda #-1
	sta (tmp),y
	jsr tp60
	inc nr
	ldx nr
	dex
	cpx data
	bcc sekdel
	bcs enddel
buch	lda cx
	beq enter1
	rts
enter1	jsr d0
	jsr tellfel
	ldx #20
	lda #0
	jsr input
	beq skp1
	lda y
	clc
	adc cy
	sbc #3
	pha
	tax
	jsr calcx
	ldy #0
cpy1	lda latch,y
	beq cpy2
	sta (tmp),y
	iny
	bne cpy1
cpy2	lda #32
cpy3	cpy #20
	bcs skp0
	sta (tmp),y
	iny
	bne cpy3
skp0	pla
	cmp data
	bcc skp1
	lda data
	cmp #maxdat
	bcs skp1
	inc data
	lda #-1
skp2	sta (tmp),y
	iny
	cpy #60
	bcc skp2
skp1	jsr cursor
	jmp out
ziffer	jsr d0
	lda cx
qenter	beq enter1
	jsr tellfel
	lda #-1
	ldx #3
	jsr input
	beq skp1
	jsr wert
	bcs skp1
setwor	pha
	lda cy
	cmp #4
	bcc zi1
	sbc #4
	clc
	adc y
	tax
	jsr calcx
	lda cx
	clc
	adc x
	adc #19
	tay
	pla
	bit art
	bpl rinne
	tax
	beq zi9
	cmp #-1
	beq rinne
	cpx #7
	bcs zi9
	lda puno,x
rinne	sta (tmp),y
	jmp zi9
zi1	sbc #0
	tax
	lda pos,x
	clc
	adc cx
	adc x
	tay
	pla
	sta opt-2,y
zi9	jsr calccut
	jmp skp1
stric	lda cx
	beq qenter
	jsr d0
	lda #-1
	bne setwor
sort	lda data
	cmp #2
	bcc nene
	lda #<updn
	ldy #>updn
	jsr strout
gud	jsr getkey
	cmp #"_"
	bne wet
nene	jmp clrob
wet	cmp #"+"
	beq sup
	cmp #"-"
	bne gud
	lda #$b0
	.byt $2c
sup	lda #$90
	sta richtung
	jsr clrob
	lda #<sorte
	ldy #>sorte
	jsr strout
dosort	lda cx
	beq czer
	clc
	adc #19
	adc x
czer	sta sortpos
	ldx data
	dex
	stx end
sor1	ldx #0
	stx nr
	stx sortflg
	jsr calcx
sor2	lda tmp
	clc
	adc #60
	sta tem
	lda tmp+1
	adc #0
	sta tem+1
	lda darst
	bne extrasort
normsort	ldy sortpos
	dey
sor3	iny
	cpy #60
	bcs sor4
	lda (tmp),y
	cmp (tem),y
	beq sor3
richtung	bcc sor4
	beq sor4
	ldy #59
sor5	lda (tmp),y
	tax
	lda (tem),y
	sta (tmp),y
	txa
	sta (tem),y
	dey
	bpl sor5
	sty sortflg
	ldy nr
	ldx sch1,y
	lda sch1+1,y
	sta sch1,y
	txa
	sta sch1+1,y
	ldx sch2,y
	lda sch2+1,y
	sta sch2,y
	txa
	sta sch2+1,y
	ldx sch3,y
	lda sch3+1,y
	sta sch3,y
	txa
	sta sch3+1,y
sor4	jsr tp60
	inc nr
	lda nr
	cmp end
	bcc sor2
	lda sortflg
	bne sor1
	beq frech1
frech	jsr d0
frech1	jsr clrob
	jmp out
extrasort	ldx cx
	beq normsort
	ldy nr
	dex
	bne nosort1
	lda sch1,y
	cmp sch1+1,y
	jmp richtung
nosort1	dex
	bne nosort2
	lda sch2,y
	cmp sch2+1,y
	jmp richtung
nosort2	lda sch3,y
	cmp sch3+1,y
	jmp richtung
schnitte	lda darst
	eor #-1
	sta darst
	bpl frech
	lda data
	beq frech
	lda art
	beq schn0
	lda #5
	bne setopt
schn0	jsr tell
	lda #<fnc
	ldy #>fnc
	jsr strout
	lda #-1
	ldx #3
	jsr input
	beq frech
	jsr wert
	bcs frech
setopt	sta bopt
	jsr byt0fac
	ldx #<opti
	ldy #>opti
	jsr facmem
	lda #<calce
	ldy #>calce
	jsr strout
	ldx #0
	stx ymem
	jsr calcx
schueler	lda #0
	sta anz
	ldx #4
clrsum1	sta add,x
	dex
	bpl clrsum1
	ldx #0
pruef1	stx xmem
	jsr getop
	beq missa
	cmp #-1
	beq missa
	pha
	txa
	clc
	adc #20
	tay
	lda (tmp),y
	cmp #-1
	beq missa2
	jsr byt0fac
	jsr facarg
	pla
	jsr byt0fac
	jsr div
	lsr vz
	lda #<opti
	ldy #>opti
	jsr memmult
	lda #<add
	ldy #>add
	jsr memplus
	ldx #<add
	ldy #>add
	jsr facmem
	inc anz
	bne missa
missa2	pla
missa	inc xmem
	ldx xmem
	cpx #40
	bcc pruef1
	lda anz
	bne ist1
	lda #-1
	bne soll1
ist1	jsr byt0fac
	lda #<add
	ldy #>add
	jsr memarg
	jsr div
	jsr int
soll1	ldy ymem
	sta sch1,y
	lda anz
	sta sch3,y
	lda #0
	sta adda
	sta adda+1
	ldx #4
clrsum2	sta add,x
	dex
	bpl clrsum2
	ldx #0
pruef2	stx xmem
	jsr getop
	beq missb
	cmp #-1
	beq missb
	pha
	txa
	clc
	adc #20
	tay
	lda (tmp),y
	cmp #-1
	beq missb2
	jsr byt0fac
	jsr facarg
	pla
	jsr byt0fac
	jsr div
	lsr vz
	lda #<opti
	ldy #>opti
	jsr memmult
	jsr facarg
	ldx xmem
	lda wer,x
	cmp #-1
	beq missb
	pha
	clc
	adc adda
	sta adda
	bcc nocry
	inc adda+1
nocry	pla
	jsr byt0fac
	lda exp
	jsr mult
	lda #<add
	ldy #>add
	jsr memplus
	ldx #<add
	ldy #>add
	jsr facmem
	jmp missb
missb2	pla
missb	inc xmem
	ldx xmem
	cpx #40
	bcc pruef2
	lda adda
	ora adda+1
	bne ist2
	lda #-1
	bne soll2
ist2	lda adda
	ldx adda+1
	jsr bytfac
	lda #<add
	ldy #>add
	jsr memarg
	jsr div
	jsr int
soll2	ldy ymem
	sta sch2,y
	jsr tp60
	ldy ymem
	inc ymem
	cpy data
	bcs hats
	jmp schueler
hats	jsr clrob
	jmp out
getop	lda art
	bne att5
	lda opt,x
	rts
att5	lda #5
	rts
datum	jsr tell
	lda #<fnd
	ldy #>fnd
	jsr strout
	ldx #52
	stx spalte
	lda #<date
	ldy #>date
	jsr strout
	ldx #8
	lda #0
	jsr input
	beq altdat
copydat	lda latch,x
	sta date,x
	dex
	bpl copydat
altdat	jmp out
printer	jsr mail
	lda data
	beq abort
	lda cy
	cmp #4
	bcc abort
	lda #<wasd
	ldy #>wasd
	jsr strout
gup	jsr getkey
	cmp #"_"
	beq abort
	cmp #"s"
	beq splt
	cmp #"z"
	bne gup
	lda #0
	.byt $2c
splt	lda #-1
	sta anz
	jsr print1
	bne nabort
abort	jmp print0
nabort	jsr return
	lda anz
	bne pspal
	jmp pzeil
pspal	lda cx
	bne ppruefs
	lda #<pt4
	ldy #>pt4
	jsr strout
	lda #0
	beq dopt2
ppruefs	lda darst
	beq realp
	lda #<pte
	ldy #>pte
	jsr flash
	beq dopt2
realp	lda #<pt9
	ldy #>pt9
	jsr strout
	lda #<pt5
	ldy #>pt5
	jsr strout
	lda x
	clc
	adc cx
	sta ax
	jsr pnum
	lda #<pt7
	ldy #>pt7
	jsr strout
	ldy ax
	lda wer-1,y
	jsr pnum
	lda #<pt8
	ldy #>pt8
	jsr strout
	bit art
	bmi usc
	lda #<pt6
	ldy #>pt6
	jsr strout
	ldy ax
	lda opt-1,y
	jsr pnum
usc	jsr return
	lda #32
dopt2	sta pt3
	lda #<pt2
	ldy #>pt2
	jsr strout
	lda darst
	beq noneed
	lda cx
	beq noneed
	lda #<ptd
	ldy #>ptd
	jsr strout
noneed	jsr return
	jsr dot
	ldx #0
spapl1	stx nr
	jsr calcx
	ldx nr
	inx
	txa
	jsr pnum
	ldy #0
spapl2	lda (tmp),y
	jsr print
	iny
	cpy #20
	bcc spapl2
	lda cx
	beq nurname
	ldx #6
	jsr xspa
	lda darst
	bne moreout
	lda #19
	clc
	adc ax
	tay
	lda (tmp),y
	jsr dpnum
nurname	jsr return
	jsr abbr
	ldx nr
	inx
	cpx data
	bcc spapl1
	jsr dot
	lda cx
	beq ferts
	lda darst
	bne ferts
	lda #<pta
	ldy #>pta
	jsr strout
	ldx #14
	jsr xspa
	ldx ax
	lda cut-1,x
	jsr dpnum
	jsr return
	jsr dot
ferts	jmp abort
moreout	jsr space
	ldx nr
	lda sch1,x
	jsr dpnum
	ldx #5
	jsr xspa
	ldx nr
	lda sch2,x
	jsr dpnum
	ldx #5
	jsr xspa
	ldx nr
	lda sch3,x
	jsr pnum
	jmp nurname
pzeil	lda #<pt9
	ldy #>pt9
	jsr strout
	lda cy
	sec
	sbc #4
	adc y
	tax
	jsr pnum
	dex
	jsr calcx
	jsr space
	ldy #0
pname	lda (tmp),y
	jsr print
	iny
	cpy #20
	bcc pname
	jsr return
	jsr return
pzens	ldy #20
	lda #34
	jsr hed
	ldy #34
	lda #48
	jsr hed
	ldy #48
	lda #60
	jsr hed
	jmp abort
hed	sta end
	sty nr
	tya
	pha
	lda #<ptb
	ldy #>ptb
	jsr strout
	ldy nr
zeip1	tya
	sec
	sbc #19
	jsr pnum
	lda #"!"
	jsr print
	inc nr
	ldy nr
	cpy end
	bcc zeip1
	jsr return
	ldx #78
	jsr rdot
	pla
	sta nr
	lda #<ptca
	ldy #>ptca
	bit art
	bpl usa
	lda #<ptcb
	ldy #>ptcb
usa	jsr strout
	ldy nr
zeip2	lda (tmp),y
	jsr dpnum
	lda #"!"
	jsr print
	inc nr
	ldy nr
	cpy end
	bcc zeip2
	jsr return
	jsr return
abbr	jsr get
	cmp #"_"
	beq ribbel
	rts
ribbel	pla
	pla
	jmp abort
mail	ldx #5
mai1	lda pt3a,x
	bit art
	bpl usb
	lda pt3b,x
usb	sta pt3+1,x
	dex
	bpl mai1
	rts
flash	jsr strout
	bit art
	bpl dej
	lda #<ptf
	ldy #>ptf
dcx	jsr strout
	lda #0
	rts
dej	lda #<ptg
	ldy #>ptg
	jsr strout
	lda bopt
	jsr psnum
	lda #<pth
	ldy #>pth
	bne dcx
artsw	jsr sure
	beq nana
	lda art
	eor #-1
	sta art
	jmp putzweg
nana	rts